Code für Wischgesten

[RehW]

Hallo zusammen,

nun mal keine Frage sondern ein Code für 8 Wischgesten:

##zwischengespeicherte Mausposition
global zMausH1,zMausV1,zMausH2,zMausV2
##Anzahl der Pixel um welche die Maus bewegt werden muss
constant zMausP=75

##Mausposition merken (Horizontal+Vertikal) beim drücken der Maustaste
on mousedown
   put the mouseH into zMausH1
   put the mouseV into zMausV1
end mousedown

##Mausposition vergleichen nach loslassen der Maustaste (min. XX Pixel)
on mouseup
   put the mouseH into zMausH2
   put the mouseV into zMausV2
   ##nur wenn die Maus um XX Pixel bewegt wurde
   if zMausV1-zMausV2>zMausP or zMausV2-zMausV1>zMausP or zMausH1-zMausH2>zMausP or zMausH2-zMausH1>zMausP then
      ##vertikale Bewegung grösser als XX Pixel
      if zMausV1-zMausV2>zMausP or zMausV2-zMausV1>zMausP then
         ##zusätzlich die horizontale Bewegung grösser als XX Pixel
         if zMausH1-zMausH2>zMausP or zMausH2-zMausH1>zMausP then
            if zMausV1>zMausV2 then
               if zMausH1>zMausH2 then
                  answer "Bewegung nach links oben"
               else
                  answer "Bewegung nach rechts oben"
               end if
            else
               if zMausH1>zMausH2 then
                  answer "Bewegung nach links unten"
               else
                  answer "Bewegung nach rechts unten"
               end if
            end if
         ##horizontale Bewegung kleiner als XX Pixel
         else
            if zMausV1>zMausV2 then
               answer "Bewegung vertikal nach oben"
            else
               answer "Bewegung vertikal nach unten"
            end if
         end if
      ##nur die horizontale Bewegung grösser als XX Pixel
      else if zMausH1-zMausH2>zMausP or zMausH2-zMausH1>zMausP then
         if zMausH1>zMausH2 then
            answer "Bewegung horizontal nach links"
         else
            answer "Bewegung horizontal nach rechts"
         end if
      end if
   end if
end mouseup

Einfach alle Zeilen mit “answer …” durch eigenen Code ersetzen. Wer nich alle Richtungen brauch kann die Abfragen einfach löschen.

Gruss Rene

[Torsten]

Hi Rene,

danke, werde ich demnächst testen!

Beste Grüße
Torsten

[Autor]

Beiträge