Antwort auf: cameraControl

[Klaus Major]

Hallo Harald,

ich besitze weder ein Handy noch ein Tablet und entwickle daher nicht für die mobile Platform.
Aber Du hast natürlich recht, das sollte auch mit CameraControl gehen. Nur kann ich dir leider nicht sagen, warum es das nicht tut.

Wie oben erwähnt, würde ich geren mal in Deinem Stack nach der Syntax schauen, aber der Server anwortet nicht.

2wei Minuten später… 🙂

OK, jetzt hat er geantwortet, Stack heruntergeladen und nachgesehen.
Das Problem, Deine beiden Buttons wissen nicths voneinander und sprchen daher zwei verschiedene cameracontrols.

Mach Folgendes:
1. Lagere die Handler in den Buttons aus ins Kartenskript und lege eine lokale Variable mit dem Namen der CameraControl an.
Kartenskript:
## DerCameraName ist nun LOKAL und kann von allen Handlern in diesem Skript benutzt werden!

local DerCameraName
local noch_n_pic

command init_camera
   put "myFirstCamera" into DerCameraName
   cameraControlCreate DerCameraName
   cameraControlSet DerCameraName, "device", "front"
   cameraControlSet DerCameraName, "rect", the rect of graphic 1
   cameraControlSet DerCameraName, "visible", true
end init_camera

command take_pic
   put true into noch_n_pic
   cameraControlDo DerCameraName, "takePicture"
   put the result into image 1

   ## wir sollten unbedingt einen "Ausgang" einbauen!
   ## Vielleicht ein button "Stop" oder so, daher:
   if noch_n_pic then
      send "take_pic" to me in 5 seconds
   end if
end take_pic

command stop_taking_pics
   put false into noch_n_pic 
end stop_taking_pics 

2. In den Buttons werden diese Handler nun nur „getriggert“.
Button „create“:

on mouseUp
   init_camera
end mouseUp

Button „take pic“:

on mouseUp
   take_pic
end mouseUp

Button „stop“, to do 🙂 ):

on mouseUp
   stop_taking_pics
end mouseUp

Gruß

Klaus