Antwort auf: MySQL Verbindung mit der Handy APP ohne Erfolg

[it-basixs]

Community Version in der Version 9.0.2, muss das erstmal testen…

Aber Du hast doch eine eingebaut “if the result…” und so?

Ja, hab ich Siehe unten. Der gesamte Code funktioniert in der IDE unter Windows 10 wunderbar, nur eben nicht auf dem Handy. Alles unwichtige habe ich mal aus dem Code gelöscht, damit das hier nicht zu Verwirrungen führt. Des Weiteren habe ich auch eine APP direkt mit dem LiveCode MySQL Tutorial unverändert erstellt und aufs Handy geladen, leider gleiches Ergebnis. In der IDE Funktioniert es als APP auf dem Handy nicht!

-- use a global variable to hold the connection ID so other scripts can use it
global gConnectionID
global dbServ
global dbName
global dbUser
global dbPass

command OpenMySQL   
   ## Zugangsdaten kommen aus Textfeldern...
   put field "dbServ" into dbServ
   put field "dbName" into dbName
   put field "dbUser" into dbUser
   put field "dbPass" into dbPass
   
   ## Bis hierhin, kein Problem 
   answer info dbServ & cr & dbName & cr & dbUser & cr & dbPass
   
   -- connect to the database
   put revOpenDatabase("mysql", dbServ, dbName, dbUser, dbPass) into tResult
   	
   -- check if it worked and display an error message if it didn't
   -- & set the connection ID global

   ## Leider keinerlei Rückmeldungen obwohl es hier steht...
   if tResult is a number then
      put tResult into gConnectionID
      answer info "Connected to the database." & cr & "Connection ID = " & gConnectionID
   else
      put empty into gConnectionID
      answer error "Unable to connect to the database:" & cr & tResult
   end if
end OpenMySQL

on hiliteChanged
   put the hilitedItemName of me into navBar
 
   if navBar = "option" then
      show group "Settings"
   else
      hide group "Settings"
   end if

   if navBar = "members" then
      show group "grdUser"
      put "Anwesenheit" into field "navText"
      
      ## Datenbank öffnen
      OpenMySQL
      
      if gConnectionID is an integer then
         ## Query the database for data
         put revQueryDatabase(gConnectionID, "SELECT LastLogInDate, UserName FROM Members WHERE PKID NOT LIKE '1' AND IsActive Like '-1' AND LID NOT LIKE '0'") into theCursor   
         
         if theCursor is an integer then
            ConvertSQLCursorToArray theCursor, theDataGridArray
            put the result into theError
            
            ## grdData löschen
            set the dgData of group "grdUser" to empty
            
            if theError is empty then
               ## The cursor was successfully converted to an array.
               ## Assign it to the data grid. The 'firstname' and 'lastname' columns
               ## from the database cursor will appear in the matching columns
               ## in the data grid.
               set the dgData of group "grdUser" to theDataGridArray
            end if
            
            ## Close the database cursor 
            revCloseCursor theCursor
         end if
         
         ## Close the database connection
         revCloseDatabase gConnectionID
      else
         answer "Error connecting to the database:" && gConnectionID & "."
      end if
   else
      hide group "grdUser"
   end if
   
end hiliteChanged

command ConvertSQLCursorToArray pCursor, @pOutArrayA
   local i
   local theFields
   local theError
   
   ## Get the names of all the columns in the database cursor
   put revDatabaseColumnNames(pCursor) into theFields
   if theFields begins with "revdberr," then
      put item 2 to -1 of theFields into theError
   end if
   
   if theError is empty then
      put 0 into i
      ## Loop through all rows in cursor
      repeat until revQueryIsAtEnd(pCursor)
         add 1 to i
         
         ## Move all fields in row into next dimension of the array
         repeat for each item theField in theFields
            put revDatabaseColumnNamed(pCursor, theField) into pOutArrayA[i][ theField ]
         end repeat
         
         revMoveToNextRecord pCursor
      end repeat
   end if
   
   return theError
end ConvertSQLCursorToArray